5 SYS 65418:POKE 808,234:POKE56,160:CLR
10 DIM SP$(4)
20 POKE53280,11:POKE53281,0:PRINT"[147]"
25 PRINT"[150]     ****  [212]HE [210]ING OF [197]LANOR  ****"
30 PRINT" [158][200]ATH THOU A PERSONA ON DISK? ";:GOSUB 2200
40 IF T$="Y" THEN PRINT"[217]ES":GOTO 1770
45 PRINT"[206]AY"
50 PRINT" [196]URST THOU WISH TO HEAR THE STORY OF    THE [204]AND OF [197]LANOR? ";
60 GOSUB 2200:IF T$="N" THEN PRINT"[206]AY":GOTO 510
65 PRINT"[217]ES"
70 A$="[147]      [212]HE [211]TORY OF [197]LANOR...":GOSUB 2500
80 A$="[155]   [201]N DAYS LONG PAST, THE WORLD WAS NOT":GOSUB 2500
90 A$="AS WE KNOW IT.  [193]MONG MORTAL MEN WALKED":GOSUB 2500
100 A$="THE [200]ORRORS OF [195]HAOS: [196]RAGONS, [196]EMONS,":GOSUB 2500
110 A$="AND OTHER DWELLERES OF DARKNESS.  [194]UT":GOSUB 2500
120 A$="THEN A GREAT [215]ARRIOR-[195]LERIC EMERGED TO":GOSUB 2500
130 A$="FIGHT [195]HAOS, AND WITH THE HELP OF HIS":GOSUB 2500
140 A$="TWO BROTHERS, HE BANISHED [195]HAOS AND ALL":GOSUB 2500
150 A$="ITS MINIONS FROM THE WORLD OF MORTAL":GOSUB 2500
160 A$="MEN.":GOSUB 2500:FORT=1TO250:NEXTT
170 A$="     [200]IS NAME WAS [197]LRIC THE [204]AWFUL.":GOSUB 2500:GOSUB 2300
180 A$="[147][155]   [200]E FOUNDED THE [195]ENTRAL [214]ILLAGE OF":GOSUB 2500
190 A$="[200]OMELAND, FOR REST AND PROTECTION.  [201]N":GOSUB 2500
200 A$="THE VILLAGE A GREAT STATUE WAS BUILT IN":GOSUB 2500
210 A$="HIS HONOR AND FORM. [212]HE [194]ROTHERS OF [204]AW":GOSUB 2500
220 A$="(AS [197]LRIC AND HIS BROTHERS HAD BECOME":GOSUB 2500
230 A$="KNOWN) CREATED THE [199]REAT [210]ING OF [197]LANOR[155]":GOSUB 2500
240 A$="AS PROTECTION FOR THE LAND AFTER THEIR":GOSUB 2500
250 A$="DEATH.  [212]HE RING WAS PLACED ON THE":GOSUB 2500
260 A$="STATUE OF [197]LRIC AND MAINTAINED A LAWFUL":GOSUB 2500
270 A$="SHIELD AROUND OUR WORLD THAT KEPT [195]HAOS":GOSUB 2500
280 A$="AT BAY.  [193]S LONG AS THE RING STAYED, SO":GOSUB 2500
290 A$="WOULD THE PEACE.":GOSUB 2500:GOSUB 2300
300 A$="[147][155]   [212]HE RING WAS SUCCESSFUL FOR MANY":GOSUB 2500
310 A$="GENERATIONS UNTIL IT MYSTERIOUSLY":GOSUB 2500
320 A$="VANISHED.  [206]OW, THE [197]VIL SLOWLY SEEPS":GOSUB 2500
330 A$="BACK TO OUR WORLD AND WILL SOON OVERRUN":GOSUB 2500
340 A$="US IF LEFT UNCHECKED.  [193]S WE SPEAK, MEN":GOSUB 2500
350 A$="AND WOMEN ARE BEING SLAUGHTERED BY THE":GOSUB 2500
360 A$="[196]EMONS.":GOSUB 2500
380 A$="   [201]T IS RUMORED THAT THE GREATEST OF":GOSUB 2500
390 A$="THE [197]VIL BEASTS HAS THE RING AND PLANS":GOSUB 2500
400 A$="TO HARNESS ITS POWER AGAINST THE VERY":GOSUB 2500
405 A$="PEOPLE IT WAS MEANT TO PROTECT.":GOSUB 2500:GOSUB 2300
410 A$="[147]   [215]ILL THE [196]RAGONS RULE THE HUMANS?":GOSUB 2500
420 A$="[195]AN THE MORTALS OF THE WORLD EVER BE":GOSUB 2500
430 A$="FREE OF [195]HAOS AGAIN? [155] [215]ELL, MY FRIEND,":GOSUB 2500
440 A$="THE ANSWERS LIE IN YOU.  [217]OU ARE OUR":GOSUB 2500
450 A$="LAST HOPE.  [212]HE FATE OF HUMANITY RESTS":GOSUB 2500:FORT=1TO250:NEXT
460 A$="UPON YOUR SHOULDERS.":GOSUB 2500
470 A$="   [199]O NOW, AND MAY THE SPIRIT OF [197]LRIC":GOSUB 2500
480 A$="THE [204]AWFUL[155] PROTECT YOU.":GOSUB 2500:GOSUB 2300
510 PRINT"[154][147]         [195]HARACTER [195]ONSTRUCTION"
520 PRINT:PRINT
530 PRINT"[152] [215]HAT DURST THY NAME?"
540 PRINT
550 PRINT"[152]>[159]";:GOSUB 3000
560 IF T$=""THEN PRINT"[145]";:GOTO 550
570 CN$=LEFT$(T$,8)
572 X$="":FOR I=1 TO LEN(CN$):A$=MID$(CN$,I,1)
574 IF ASC(A$)>192 AND ASC(A$)<219 THEN A$=CHR$(ASC(A$)-128)
576 X$=X$+A$:NEXT
580 PRINT
590 PRINT"[152] [215]HAT MANNER OF MAN ARE YE?"
595 PRINT " ([197]LF, [195]LERIC, OR [200]UMAN)"
600 PRINT">[159][164]";
605 GET T$:IF T$="" THEN 605
607 IF T$="" THEN SS=-255
610 IF T$<>"E"AND T$<>"H"AND T$<>"C"THEN605
611 PRINT"[157]";
612 IF T$="E" THEN R$="[197]LF":PRINTR$
614 IF T$="C" THEN R$="[195]LERIC":PRINTR$
616 IF T$="H" THEN R$="[200]UMAN":PRINTR$
620 PRINT
630 L=1:PRINT"[151][204]EVEL ";L
640 PRINT
650 S=INT(RND(1)*14)+1:IF R$="[200]UMAN"THEN S=S+4:IF S>15THEN S=15
660 IF R$="[195]LERIC"THEN S=S-2:IF S<1THEN S=1
670 I=INT(RND(1)*14)+1:IF R$="[195]LERIC"THEN I=I+2:IFI>15THENI=15
680 C=INT(RND(1)*14)+1:IF R$="[200]UMAN"THENC=C-2:IFC<1THENC=1
690 D=INT(RND(1)*14)+1:CH=INT(RND(1)*14)+1
700 SL=INT(RND(1)*40)+50:EX=0
710 HP=INT(RND(1)*C)+4:H=HP
720 IF R$="[197]LF"THENAC=6
730 IF R$="[200]UMAN"THENAC=5
740 IF R$="[195]LERIC"THENAC=7
750 IFS+D>22THENAC=AC-2
760 PRINT"[152] [211]TRENGTH    -[155]";S;"[157] [152]"
770 PRINT" [201]NTELLIGENCE-[155]";I;"[157] [152]"
780 PRINT" [195]ONSTITUTION-[155]";C;"[157] [152]"
790 PRINT" [196]EXTERITY   -[155]";D;"[157] [152]"
800 PRINT" [195]HARISMA    -[155]";CH;"[157] [152]"
810 PRINT" [200]IT [208]OINTS  -[155]";HP;"[157] [152]"
820 PRINT" [193]RMOUR [195]LASS-[155]";AC;"[157] [152]"
830 PRINT:PRINT
840 IFSS>3THEN870
850 PRINTTAB(11)"[158][193]RT YE SATISFIED?":GOSUB 2200
860 IF T$="N"THENSS=SS+1:PRINT"[145][145][145][145][145][145][145][145][145][145][145]":GOTO650
870 PRINT"[147]";
880 PRINT"                         [146]"
890 PRINT" [146]*** [195]HARACTER [211]HEET *** [146]"
900 PRINT"                                       [146]"
910 FORT=1TO7:PRINT" [146]                                      [146]":NEXTT
920 PRINT"                                       [146]"
930 PRINT""
940 PRINTTAB(19)" [146]"
950 PRINT" [206]AME:   [158]";CN$;TAB(19)" [146]";" [211]TRENGTH:    [158]";S
960 PRINT" [210]ACE:   [158]";R$;TAB(19)" [146]";" [201]NTELLIGENCE:[158]";I
970 PRINT" [204]EVEL: [158]";L;TAB(19)" [146]";" [195]ONSTITUTION:[158]";C
980 PRINT" [211]ILVER:[158]";SL;TAB(19)" [146]";" [196]EXTERITY:   [158]";D
990 PRINT" [197]XPER: [158]";EX;TAB(19)" [146]";" [195]HARISMA:    [158]";CH
1000 PRINTTAB(19)" [146]"
1010 PRINT
1020 PRINT"                                       [146]"
1030 PRINT" [146] [200]IT [208]OINTS:[158]";HP;TAB(19);"  [193]RMOUR [195]LASS:[158]";AC;TAB(38)" [146]"
1040 PRINT"                                       [146]"
1050 IF R$="[197]LF"THEN NS=2
1060 IF R$="[200]UMAN"THEN NS=1
1070 IF R$="[195]LERIC"THEN NS=3
1080 PRINT
1090 IF INT(I/5)=>2THEN1310
1100 IF INT(I/5)=1THEN 1210
1110 FOR T=1TO NS
1120 R=INT(RND(1)*4):IF R=0THEN SP$(T)="[205]AGIC [205]ISSLE"
1130 IF R=1THEN SP$(T)="[195]REATE [198]OOD"
1140 IF R=2THEN SP$(T)="[204]IGHT"
1150 IF R=3THEN SP$(T)="[200]EALING"
1160 IF T=1THEN 1190
1170 IF SP$(T)=SP$(T-1) THEN 1120
1180 IF T=3AND SP$(T)=SP$(T-2)THEN 1120
1190 NEXT T
1200 GOTO1400
1210 FOR T=1TO NS
1220 R=INT(RND(1)*4):IF R=0THEN SP$(T)="[201]NVISIBILITY"
1230 IF R=1 THEN SP$(T)="[195]REATE [198]OOD"
1240 IF R=2 THEN SP$(T)="[200]EALING"
1250 IF R=3 THEN SP$(T)="[215]EB"
1260 IF T=1 THEN 1290
1270 IFSP$(T)=SP$(T-1)THEN1220
1280 IF T=3AND SP$(T)=SP$(T-2)THEN1220
1290 NEXT T
1300 GOTO1400
1310 FORT=1TONS
1320 R=INT(RND(1)*4):IFR=0THEN SP$(T)="[198]IREBALL"
1330 IF R=1THEN SP$(T)="[195]REATE [198]OOD"
1340 IF R=2THEN SP$(T)="[200]ASTE"
1350 IF R=3THENSP$(T)="[211]UPER [200]EAL"
1360 IF T=1THEN 1390
1370 IF T=3AND SP$(T)=SP$(T-2)THEN1320
1380 IF SP$(T)=SP$(T-1)THEN 1320
1390 NEXT T
1400 PRINT"[211]PELLS:[158]"
1410 FOR T=1TO NS
1420 PRINT" ";SP$(T)
1430 NEXTT
1440 PRINT:PRINT"   [155][196]O YOU WISH TO KEEP THIS PERSONA?"
1445 GOSUB 2200
1450 IF T$="N"THEN SS=0:GOTO 510
1470 PRINT" [208]RESS <[210][197][212][213][210][206]>[155] WHEN THE DISK IS READY"
1475 GOSUB 2310
1478 OPEN 15,8,15,"I0":GOSUB 2600
1479 PRINT#15,"S0:"+X$
1480 OPEN2,8,2,"0:"+X$+",S,W"
1485 GOSUB 2600
1490 PRINT#2,CN$
1500 PRINT#2,R$
1510 PRINT#2,L
1520 PRINT#2,SL
1530 PRINT#2,EX
1540 PRINT#2,S
1550 PRINT#2,I
1560 PRINT#2,C
1570 PRINT#2,D
1580 PRINT#2,CH
1590 PRINT#2,H
1600 PRINT#2,HP
1610 PRINT#2,AC
1620 PRINT#2,NS
1630 FOR T=1TO NS:PRINT#2,SP$(T):PRINT#2,"1":NEXTT
1640 FOR T=1TO 13:READ OB$:PRINT#2,OB$:PRINT#2,"0":NEXTT
1650 PRINT#2,0
1660 PRINT#2,18:PRINT#2,11:REM X,Y
1670 PRINT#2,10:PRINT#2,0:REM FOOD,ARROWS
1680 PRINT#2,1:REM SPEED
1690 PRINT#2,0:REM TIME
1700 CLOSE 2
1770 PRINT"[147]                                       "
1780 FORT=1TO16:PRINT"  [146]                                     [146]":NEXTT
1790 PRINT"                                       [146]"
1800 PRINT"                                    "
1810 FOR T=1TO14:PRINT" [146]                                   [146]":NEXTT
1820 PRINT"                                    "
1830 PRINT"[152]           [206]OW [204]OADING"
1835 PRINTTAB(18)"[212]HE"
1840 PRINT"        * [210]ING OF [197]LANOR *"
1860 PRINT"[144]LOAD"CHR$(34)"0:ELANOR.EXE"CHR$(34)",8:":PRINT"RUN:[145][145][145][145]"
1870 POKE 198,2:POKE 631,13:POKE 632,13
1900 END
1910 DATA "[211]WORD","[194]ROADSWORD","[211]ILVER DAGGER","[205]ACE","[194]OW"
1920 DATA "[211]HIELD","[193]RMOUR","[200]ORSE","[212]ORCH","50' ROPE","[204]ANTERN","[194]ACKPACK"
1930 DATA "[210]ING OF [197]LANOR"
2200 POKE 198,0
2210 GET T$:IF T$<>"Y" AND T$<>"N" THEN 2210
2220 RETURN
2300 PRINTTAB(16)"[158]<[210][197][212][213][210][206]>";
2310 GET A$:IF A$<>CHR$(13) THEN 2310
2320 RETURN
2500 FOR I=1 TO LEN(A$):PRINTMID$(A$,I,1);
2510 FOR J=1 TO 40:NEXT
2520 NEXT I
2530 PRINT:PRINT:RETURN
2600 INPUT#15,ER,EM$
2610 IF ER<20 THEN RETURN
2620 CLOSE 2:CLOSE 15
2630 PRINT"[147]    [196]ISK ERROR!"ER","EM$
2640 PRINTTAB(8)"[208]RESS [210][197][212][213][210][206] WHEN READY"
2650 GET A$:IF A$<>CHR$(13) THEN 2650
2660 RUN
3000 T$="":PRINT"[164]";
3010 GET A$:IF A$="" THEN 3010
3020 A=ASC(A$)
3030 IF A=13 THEN PRINT"[157] ":RETURN
3040 IF A=20 AND LEN(T$)=0 THEN 3010
3050 IF A=20 THEN T$=LEFT$(T$,LEN(T$)-1):PRINT"[157][157]  [157][157][164]";
3055 IF LEN(T$)=20 THEN 3010
3060 IF A<32 OR A>218 THEN 3010
3070 IF A>90 AND A<193 THEN 3010
3080 IF A=34 THEN 3010
3090 T$=T$+A$
3100 PRINT"[157]"A$"[164]";
3110 GOTO 3010